dnl
dnl добавление поля Message-Id
dnl по умолчанию начиная с версии 4.30 поле Message-Id добавляется только в локально
dnl полученные сообщения (не по SMTP)
dnl несколько значений (кроме NO) могут быть перечислены через пробел в виде списка
dnl NO			- ну добавлять поле MEssage-Id
dnl RELAY		- добавлять поле Message-Id в сообщения от relay_from_hosts
dnl AUTH		- добавлять поле Message-Id в сообщения от аутентифицированных отправителей
dnl ALL			- добавлять поле Message-Id во все сообщения
dnl define(`confMESSAGE_ID_HEADER_ADD', `RELAY AUTH')dnl
dnl доменная часть поля Message-Id
dnl по умолчанию используется $primary_hostname
dnl define(`confMESSAGE_ID_HEADER_DOMAIN', `')dnl
dnl
ifelse(SECTION, `MAIN', `dnl
ifdef(`confMESSAGE_ID_HEADER_DOMAIN', `ifelse(len(X`'confMESSAGE_ID_HEADER_DOMAIN), `1', `dnl
define(`confMESSAGE_ID_HEADER_DOMAIN', `$primary_hostname')
', `dnl
message_id_header_domain = confMESSAGE_ID_HEADER_DOMAIN
')', `dnl
define(`confMESSAGE_ID_HEADER_DOMAIN', `$primary_hostname')
')
')dnl
dnl
ifelse(SECTION, `ACL_CHECK_DATA', `dnl
dnl
ifelse_strstr(confMESSAGE_ID_HEADER_ADD, `ALL', `dnl
	warn	condition	= ${if def:h_Message-ID:{no}{yes}}
		message		= Message-ID: <E${message_id}@confMESSAGE_ID_HEADER_DOMAIN>
', `dnl
ifelse_strstr(confMESSAGE_ID_HEADER_ADD, `RELAY', `dnl
	warn	hosts		= +relay_from_hosts
		condition	= ${if def:h_Message-ID:{no}{yes}}
		message		= Message-ID: <E${message_id}@confMESSAGE_ID_HEADER_DOMAIN>
')
ifelse_strstr(confMESSAGE_ID_HEADER_ADD, `AUTH', `dnl
	warn	authenticated	= *
		condition	= ${if def:h_Message-ID:{no}{yes}}
		message		= Message-ID: <E${message_id}@confMESSAGE_ID_HEADER_DOMAIN>
')
')
')