dnl
dnl проверка писем на вирусы с помощью нескольких антивирусов для:
dnl 1. exiscan-acl-4.30-14+ и patch-src::malware.c
dnl https://mta.org.ua/exim/patches/exiscan-acl-4.32-17-malware/patch-src::malware.c
dnl
ifelse(SECTION, `MAIN', `dnl
dnl
ifdef(`confAV_SCANNER', `',`dnl
errprint(`
*** ERROR: variable confAV_SCANNER required for feature antivirus.m4
example:
define(`confAV_SCANNER', `clamd:/var/run/clamav/clamd.sock : drweb:/usr/local/drweb/run/drwebd.sock')

')')
dnl
av_scanner = confAV_SCANNER
')dnl
ifelse(SECTION, `ACL_CHECK_DATA', `dnl
ifelse(confUSE_ANTIVIRUSES, `WARN', `dnl
	# Предупреждение при получении письма с вирусом
	warn	malware		= *
		set acl_m0	= ${if match{$malware_name}\
				{\N^([^:]+):\s*(.+)$\N}{$1 found a virus: $2}{Found a virus: $malware_name}}
		message		= X-Virus: $acl_m0
		log_message	= $acl_m0
')dnl
ifelse(confUSE_ANTIVIRUSES, `REJECT', `dnl
	# Запрет на приём писем с вирусами
	deny	malware		= *
		message		= ${if match{$malware_name}\
				{\N^([^:]+):\s*(.+)$\N}{$1 found a virus: $2}{Found a virus: $malware_name}}
')dnl
')dnl