include(confFEATURES_DIR`/cfhead.m4')dnl
include(confM4_DIR`/conf.default')dnl
include(confSITE_DIR/`conf')dnl

changequote(<<, >>)
link_add() {
	file=`basename $2`
	if [ -f $3/${file} ] || [ -h $3/${file} ]; then rm $3/${file}; fi
	ln -s $1/${file} $3/
}

link_del() {
	file=`basename $2`
	if [ -f $3/${file} ] || [ -h $3/${file} ]; then rm $3/${file}; fi
}
changequote

link_add confPERIODIC_DIR delete_old_warnings.sh confPERIODIC

define(`USE_QUARANTINE', `NO')
ifdef(`confANTIVIRUS1_ACT',		`define(`USE_QUARANTINE', `YES')')
ifelse_strstr(USE_QUARANTINE`'_AV_QUARANTINE_, `YES', `
link_add confPERIODIC_DIR clear_quarantine.sh confPERIODIC
', `
link_del confPERIODIC_DIR clear_quarantine.sh confPERIODIC
')

ifelse(_AV_NO_MBOX_UNSPOOL_, `YES', `
link_add confPERIODIC_DIR clear_scan.sh confPERIODIC
', `
link_del confPERIODIC_DIR clear_scan.sh confPERIODIC
')

ifelse(confCHECK_OPEN_PROXY, `NO', `
link_del confPERIODIC_DIR proxycheck_del_expired.sh confPERIODIC
', `
link_add confPERIODIC_DIR proxycheck_del_expired.sh confPERIODIC
')

ifelse(confGREYLIST_DBM, `NO', `
link_del confPERIODIC_DIR greylist_del_expired.sh confPERIODIC
', `
link_add confPERIODIC_DIR greylist_del_expired.sh confPERIODIC
')

changequote(<<, >>)
if [ ! -z "`ls confPERIODIC_SITE_DIR/* 2>/dev/null`" ]; then
	for f in confPERIODIC_SITE_DIR/* ; do \
		link_add confPERIODIC_SITE_DIR $f confPERIODIC
	done
fi
changequote