include(confFEATURES_DIR`/cfhead.m4')dnl
include(confM4_DIR`/conf.default')dnl
include(confSITE_DIR/`conf')dnl

ifdef(`confEXIM_USER',
`EXIM_USER=confEXIM_USER',
`EXIM_USER=mailnull'
)

ifdef(`confEXIM_GROUP',
`EXIM_GROUP=confEXIM_GROUP',
`EXIM_GROUP=mail'
)

system_filter_user=confSYSTEM_FILTER_USER
system_filter_group=${EXIM_GROUP}

# создание log-файла системного фильтра
touch /var/log/exim/filterlog
chown ${system_filter_user}:${system_filter_group} /var/log/exim/filterlog
chmod 640 /var/log/exim/filterlog

# создание каталога для warning-ов
system_filter_warnings_dir=confSYSTEM_FILTER_WARNINGS_DIR
if [ ! -d ${system_filter_warnings_dir} ] ; then
    mkdir -p ${system_filter_warnings_dir}
fi
chown -R ${system_filter_user}:${system_filter_group} ${system_filter_warnings_dir}
chmod 770 ${system_filter_warnings_dir}

define(`USE_QUARANTINE', `NO')
ifdef(`confANTIVIRUS0_ACT',		`define(`USE_QUARANTINE', `YES')')
ifelse(USE_QUARANTINE, `YES', `
# создание карантина
quarantine_dir=confQUARANTINE_DIR
if [ ! -d ${quarantine_dir} ] ; then
    mkdir -p ${quarantine_dir}
fi
chown -R ${system_filter_user}:${system_filter_group} ${quarantine_dir}
chmod 770 ${quarantine_dir}
')

ifelse_strstr(confDELIVERY_TO, `MDIR_VIRTUAL', `
# создание каталога с виртуальными maildir-ами
imapd_user=confVIRT_MDIR_USER
imapd_group=${EXIM_GROUP}
spool_dir=confVIRT_MDIR_ROOT

if [ ! -d ${spool_dir} ] ; then
    mkdir -p ${spool_dir}
fi
chown -R ${imapd_user}:${imapd_group} ${spool_dir}
chmod 750 ${spool_dir}
chmod 750 ${spool_dir}/*

for domain in ${spool_dir}/*; do
	chmod 700 ${domain}/*
done
')

ifelse(confCHECK_OPEN_PROXY, `NO', `', `
# создание кеша проверки на open proxy
PROXYCHECK_DBM=confCHECK_OPEN_PROXY_CACHE
PROXYCHECK_TMP=/tmp/proxycheck
if [ -f ${PROXYCHECK_TMP} ]; then rm ${PROXYCHECK_TMP} 2>/dev/null; fi
touch ${PROXYCHECK_TMP}
exim_dbmbuild ${PROXYCHECK_TMP} ${PROXYCHECK_DBM}
rm ${PROXYCHECK_TMP} 2>/dev/null
chown ${EXIM_USER}:${EXIM_GROUP} ${PROXYCHECK_DBM}
chmod 640 ${PROXYCHECK_DBM}
')

ifelse(confGREYLIST_DBM, `NO', `', `
# создание кеша greylisting-а
GREYLIST_DBM=confGREYLIST_DBM_CACHE
if [ ! -f ${GREYLIST_DBM} ]; then
    GREYLIST_TMP=/tmp/greylist
    if [ -f ${GREYLIST_TMP} ]; then rm ${GREYLIST_TMP} 2>/dev/null; fi
    touch ${GREYLIST_TMP}
    exim_dbmbuild ${GREYLIST_TMP} ${GREYLIST_DBM}
    rm ${GREYLIST_TMP} 2>/dev/null
    chown ${EXIM_USER}:${EXIM_GROUP} ${GREYLIST_DBM}
    chmod 640 ${GREYLIST_DBM}
fi
')

ifdef(`confSTARTTLS', `ifelse(confSTARTTLS, `NO', `dnl', `dnl
ifdef(`confEXIM_USER', `',`define(`confEXIM_USER',`mailnull')')
ifdef(`confEXIM_GROUP',`',`define(`confEXIM_GROUP',`mail')')
define(`CONFDIR', confCONFDIR)dnl
chmod 440 confTLS_CERTIFICATE confTLS_PRIVATEKEY
chown confEXIM_USER:confEXIM_GROUP confTLS_CERTIFICATE confTLS_PRIVATEKEY
')')

ifelse_strstr(confDELIVERY_TO, `CYRUS', `define(`USE_CYRUS',`YES')',`define(`USE_CYRUS',`NO')')

changequote(<<, >>)
ifelse(USE_CYRUS, <<YES>>, <<
CYRUS_MBPATH_PATH=confCYRUS_MBPATH_PATH
chgrp `ls -l /var/imap/mailboxes.db | awk "{print \\$4}"` ${CYRUS_MBPATH_PATH}
chmod g+s ${CYRUS_MBPATH_PATH}
chmod g+rw /var/imap/mailboxes.db
>>)
changequote

if [ -d ../hacks ] ; then
    rm -rf ../hacks
fi