dnl
dnl Доставка в dbmail
dnl
dnl локальная доставка (список)
dnl DBMAIL_PIPE		- доставка в dbmail через pipe
dnl DBMAIL_LMTP		- доставка в dbmail через lmtp
dnl define(`confDELIVERY_TO', `DBMAIL_PIPE')dnl
dnl
dnl при наличии DBMAIL_PIPE в confDELIVERY_TO:
dnl	путь к dbmail-smtp:
dnl define(`confDBMAIL_SMTP_PATH', `/usr/local/sbin/dbmail-smtp')dnl
dnl	пользователь, от имени которого выполняется  dbmail-smtp
dnl define(`confDBMAIL_SMTP_USER', `dbmail')dnl
dnl define(`confDBMAIL_SMTP_USER', `mailnull')dnl
dnl
dnl при наличии DBMAIL_LMTP в confDELIVERY_TO:
dnl 	LMTP хост:
dnl define(`confDBMAIL_LMTP_HOST', `localhost')dnl
dnl 	LMTP порт:
dnl define(`confDBMAIL_LMTP_PORT', `lmtp')dnl
dnl
dnl dbmail backend:
dnl MYSQL		- использовать хранилище учетной информации и почты в MySQL 
dnl PGSQL		- использовать хранилище учетной информации и почты в PgSQL 
dnl define(`confDBMAIL_BACKEND', `MYSQL')dnl
dnl
dnl список доменов, почту которых нужно доставлять в dbmail,
dnl указывается в файле domains-dbmail
dnl
dnl в файле skip_dbmail_check перечисляются адреса получателей, для которых
dnl нет необходимости проводить проверку получателя
dnl
dnl список указывается в виде:
dnl domain : addr1 : addr2 : addr3
dnl пример:
dnl zuper.domain.com : user : info : admin
dnl

ifelse(SECTION, `MAIN', `dnl
domainlist      dbmail_domains		= lsearch;CONFDIR/domains-dbmail

define(`DNSLOOKUP_DOMAINS', DNSLOOKUP_DOMAINS` : ! +dbmail_domains')dnl
')

ifelse(SECTION, `ACL_CHECK_RCPT', `dnl
	# Проверка существования получетеля из домена dbmail
	deny	domains		= +dbmail_domains
		! recipients	= @@wildlsearch;CONFDIR/skip_dbmail_check
		message		= Unrouteable address
		! verify	= recipient/callout
')

ifelse(SECTION, `ACL_CHECK_RCPT_BOTTOM', `dnl
	# Прием почты для получателей из домена dbmail
	accept  domains         = +dbmail
		endpass
')

changequote(<<, >>)
ifelse(SECTION, <<ROUTERS>>, <<dnl

dbmail:
	driver        = accept
	domains       = +dbmail_domains
ifelse(confDBMAIL_BACKEND, <<MYSQL>>, <<dnl
	condition     = ${lookup mysql{SELECT userid FROM dbmail_users WHERE userid="${quote_mysql:$local_part@$domain}"} \
			{yes}{\
			    ${lookup mysql{SELECT alias FROM dbmail_aliases WHERE \
			    alias="${quote_mysql:$local_part@$domain}" OR alias="${quote_mysql:@$domain}"}\
			    {yes}{no}}\
			}}
>>)
ifelse(confDBMAIL_BACKEND, <<PGSQL>>, <<dnl
	condition     = ${lookup pgsql{SELECT userid FROM dbmail_users WHERE userid='${quote_pgsql:$local_part@$domain}'} \
			{yes}{\
			    ${lookup pgsql{SELECT alias FROM dbmail_aliases WHERE \
			    alias='${quote_pgsql:$local_part@$domain}' OR alias='${quote_pgsql:@$domain}'}\
			    {yes}{no}}\
			}}
>>)
ifelse_strstr2(confDELIVERY_TO, <<DBMAIL_PIPE>>, <<
	transport     =  dbmail_pipe
>>)
ifelse_strstr2(confDELIVERY_TO, <<DBMAIL_LMTP>>, <<
	transport     =  dbmail_lmtp
>>)
	cannot_route_message = DBMAIL delivery failed

>>) dnl ifelse(SECTION, <<ROUTERS>>, <<>>)
changequote

ifelse(SECTION, `TRANSPORTS', `dnl

ifelse_strstr(confDELIVERY_TO, `DBMAIL_PIPE', `dnl
dbmail_pipe:
	driver		= pipe
	command		= "confDBMAIL_SMTP_PATH -d $local_part@$domain"
	return_fail_output
	user		= confDBMAIL_SMTP_USER
') dnl ifelse_strstr(confDELIVERY_TO, `DBMAIL_PIPE', `')

ifelse_strstr(confDELIVERY_TO, `DBMAIL_LMTP', `dnl
dbmail_lmtp:
	driver		= smtp
	protocol	= lmtp
	hosts		= confDBMAIL_LMTP_HOST
	port		= confDBMAIL_LMTP_PORT
	allow_localhost
	return_path_add
') dnl ifelse_strstr(confDELIVERY_TO, `DBMAIL_LMTP', `')

') dnl ifelse(SECTION, `TRANSPORTS', `')