dnl
dnl Доставка в users mailboxs
dnl
dnl локальная доставка (список)
dnl MBOX		- доставка в mailbox'ы в /var/mail
dnl 			с MBOX можно указывать через пробел:
dnl 			FILTERS	 - использование .forward в качестве фильтров
dnl 			PROCMAIL - использование .procmailrc в качестве фильтров
dnl MDIR_USER		- доставка в maildir'ы в $home/Maildir (еще не работает)
dnl 			с MDIR_USER можно указывать через пробел:
dnl 			FILTERS	 - использование .forward в качестве фильтров
dnl 			PROCMAIL - использование .procmailrc в качестве фильтров
dnl define(`confDELIVERY_TO', `MBOX FILTERS PROCMAIL')dnl
dnl
dnl при наличии MBOX или MDIR_USER в confDELIVERY_TO:
dnl
dnl 	место хранения алиасов:
dnl 	TEXT		- хранение алиасов в текстовом файле
dnl 	DBM		- хранение алиасов в DBM файле
dnl define(`confSYSTEM_ALIASES', `DBM')dnl
dnl
ifelse(SECTION, `ROUTERS', `dnl
system_aliases:
	driver			= redirect
	domains			= +local_domains
ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `dnl', `dnl
	local_part_suffix       = confLOCAL_PART_SUFFIX
	local_part_suffix_optional
')')
	allow_fail
	allow_defer
ifdef(`confSYSTEM_ALIASES', `ifelse(confSYSTEM_ALIASES, `TEXT', `dnl
	require_files		= CONFDIR/aliases
	data			= ${lookup{$local_part}lsearch{CONFDIR/aliases}}
')')
ifdef(`confSYSTEM_ALIASES', `ifelse(confSYSTEM_ALIASES, `DBM', `dnl
	require_files		= CONFDIR/aliases.db
	data			= ${lookup{$local_part}dbm{CONFDIR/aliases.db}}
')')
	user			= confEXIM_USER
	group			= confEXIM_GROUP
	file_transport		= address_file
	pipe_transport		= address_pipe

ifelse_strstr(confDELIVERY_TO, `PROCMAIL', `dnl
DELIVERY(`procmail')dnl
')

userforward:
	driver			= redirect
	domains			= +local_domains
ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `dnl', `dnl
	local_part_suffix       = confLOCAL_PART_SUFFIX
	local_part_suffix_optional
')')
	check_local_user
	file			= $home/.forward
	no_verify
	no_expn
	check_ancestor
	file_transport		= address_file
	pipe_transport		= address_pipe
	reply_transport		= address_reply
	require_files		= $home/.forward
ifelse_strstr(confDELIVERY_TO, `FILTERS', `dnl
	allow_filter
')

DELIVERY(`backup_incoming')dnl

localuser:
	driver			= accept
	domains			= +local_domains
ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `dnl', `dnl
	local_part_suffix       = confLOCAL_PART_SUFFIX
	local_part_suffix_optional
')')
	check_local_user
	transport		= local_delivery
ifelse_strstr(confDELIVERY_TO, `MDIR_VIRTUAL', `ifelse_strstr(confVIRT_MDIR_USERLIST, `DOMAINS_FILES', `
	condition		= ${if exists{confVIRT_MDIR_DOMAIN_SETTINGS/${domain}}{no}{yes}}
')')
	ifdef(`confHEADERS_REMOVE_LOCALUSER', `headers_remove		= confHEADERS_REMOVE_LOCALUSER
')dnl
')
dnl
ifelse(SECTION, `TRANSPORTS', `dnl
local_delivery:
	driver			= appendfile
	file			= /var/mail/$local_part
	delivery_date_add
	envelope_to_add
	return_path_add
	group			= mail
	user			= $local_part
	mode			= 0640
	no_mode_fail_narrower
ifelse_strstr(confDSN, `LOCAL', `dnl
# DSN support for local recipients
	shadow_transport	= DSN_local
	shadow_condition	= ${if and{\
				    {!eq{${extract{Return_Receipt_To}{$acl_m19}}}{}}\
				    {match{${extract{rcpt}{$acl_m19}}}{, ${original_local_part}@${original_domain},}}\
				}{yes}{no}}
') dnl
')