dnl игнорирование доставки с помощью procmail писем, предназначенных для доставки в персональный карантин
dnl define(`confVIRT_MDIR_PROCMAIL_IGNORE_PERSONAL_QUARANTINE', `YES')
dnl

ifelse_strstr(confDELIVERY_TO, `MDIR_VIRTUAL', `dnl

ifelse(SECTION, `ROUTERS', `dnl
procmail:
	driver			= accept
ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `dnl', `dnl
	local_part_suffix	= confLOCAL_PART_SUFFIX
	local_part_suffix_optional
')')
dnl
define(`_IGNORE_PERSONAL_QUARANTINE_',`NO')
ifelse_strstr(confCONTENT_SCANNING_QUARANTINE, `PERSONAL', `dnl
ifdef(`confVIRT_MDIR_PROCMAIL_IGNORE_PERSONAL_QUARANTINE', `ifelse(confVIRT_MDIR_PROCMAIL_IGNORE_PERSONAL_QUARANTINE, `YES', `dnl
define(`_IGNORE_PERSONAL_QUARANTINE_',`YES')
')')dnl ifdef(`confVIRT_MDIR_PROCMAIL_IGNORE_PERSONAL_QUARANTINE', `ifelse(confVIRT_MDIR_PROCMAIL_IGNORE_PERSONAL_QUARANTINE, `YES', `')')
')dnl ifelse_strstr(confCONTENT_SCANNING_QUARANTINE, `PERSONAL', `')
dnl
ifelse_strstr(confVIRT_MDIR_USERLIST, `LDAP', `dnl
#	require_files		= confVIRT_MDIR_PATH_LDAP/.procmailrc
	address_data		= ${lookup ldapm{\
				confVIRT_MDIR_LDAP\
				}{${sg{$value}{\N(\n.*)$\N}{}}}fail}
ifelse(_IGNORE_PERSONAL_QUARANTINE_, `YES', `dnl
	condition		= ${if and{\
				    {eq{$acl_m_quarantined}{}}\
				    {exists{ifdef(`confVIRT_MDIR_PATH_LDAP', confVIRT_MDIR_PATH_LDAP, `${extract{maildir}{$address_data}}').procmailrc}}\
				}{yes}{no}}
',`
	condition		= ${if exists{ifdef(`confVIRT_MDIR_PATH_LDAP', confVIRT_MDIR_PATH_LDAP, `${extract{maildir}{$address_data}}').procmailrc}{yes}{no}}
') dnl ifelse(_IGNORE_PERSONAL_QUARANTINE_, `YES', `')
',`dnl
ifelse(_IGNORE_PERSONAL_QUARANTINE_, `YES', `dnl
	condition		= ${if eq{$acl_m_quarantined}{}{yes}{no}}
') dnl ifelse(_IGNORE_PERSONAL_QUARANTINE_, `YES', `')
	require_files		= confVIRT_MDIR_PATH/.procmailrc
') dnl ifelse_strstr(confVIRT_MDIR_USERLIST, `LDAP', `')
	no_verify
	no_expn
	user			= confVIRT_MDIR_USER
	transport		= procmail_pipe
')
dnl
ifelse(SECTION, `TRANSPORTS', `dnl
procmail_pipe:
	driver			= pipe
ifelse_strstr(confVIRT_MDIR_USERLIST, `LDAP', `dnl
	current_directory	= confVIRT_MDIR_PATH_LDAP
',`dnl
	current_directory	= confVIRT_MDIR_PATH
') dnl ifelse_strstr(confVIRT_MDIR_USERLIST, `LDAP', `')
	command			= confPROCMAIL_PATH -p -m .procmailrc
	return_path_add
	delivery_date_add
	envelope_to_add
	check_string		= "From "
	escape_string		= ">From "
	user			= confVIRT_MDIR_USER
	group			= confVIRT_MDIR_GROUP

	umask			= 0022

#	no_freeze_exec_fail
#	no_log_defer_output
#	no_log_fail_output
#	no_log_output
#	no_return_fail_output
#	return_output
#	no_return_output
ifelse_strstr(confDSN, `LOCAL', `dnl
# DSN support for local recipients
	shadow_transport	= DSN_local
	shadow_condition	= ${if and{\
				    {!eq{${extract{Return_Receipt_To}{$acl_m19}}}{}}\
				    {match{${extract{rcpt}{$acl_m19}}}{, ${original_local_part}@${original_domain},}}\
				}{yes}{no}}
')dnl
')

',`

ifelse(SECTION, `ROUTERS', `dnl
procmail:
	driver			= accept
ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `dnl', `dnl
	local_part_suffix	= confLOCAL_PART_SUFFIX
	local_part_suffix_optional
')')
	check_local_user
	no_verify
	no_expn
	user			= ${local_part}
	require_files		= ${home}/.procmailrc
	transport		= procmail_pipe
')
dnl
ifelse(SECTION, `TRANSPORTS', `dnl
procmail_pipe:
	driver			= pipe
#	return_output
	delivery_date_add
	envelope_to_add
	return_path_add
	command			= confPROCMAIL_PATH -p -d $local_part
	user			= ${local_part}
	group			= confEXIM_GROUP
#	umask			= 0022
	no_freeze_exec_fail
	no_log_defer_output
	no_log_fail_output
	no_log_output
	no_return_fail_output
	no_return_output
ifelse_strstr(confDSN, `LOCAL', `dnl
# DSN support for local recipients
	shadow_transport	= DSN_local
	shadow_condition	= ${if and{\
				    {!eq{${extract{Return_Receipt_To}{$acl_m19}}}{}}\
				    {match{${extract{rcpt}{$acl_m19}}}{, ${original_local_part}@${original_domain},}}\
				}{yes}{no}}
')dnl
ifdef(`confMAIL_BACKUP', `ifelse_strstr(confMAIL_BACKUP, `ROUTER_REDIRECT', `
	headers_remove		= ${if eq{$local_part@$domain}{confMAIL_BACKUP_ADDR}{}{X-Recipients}}
')')
')

')