ifelse(SECTION, `MAIN', `dnl
## Mailman config
# Home dir for your Mailman installation -- aka Mailman"s prefix
# directory.
MAILMAN_HOME=confMAILMAN_HOME
MAILMAN_WRAP=MAILMAN_HOME/mail/mailman

# User and group for Mailman, should match your --with-mail-gid
# switch to Mailman"s configure script.
ifdef(`confEXIM_USER',
`MAILMAN_USER = confEXIM_USER',
`MAILMAN_USER = mailnull'
)
ifdef(`confMAILMAN_GROUP',
`MAILMAN_GROUP = confMAILMAN_GROUP',
`
ifdef(`confEXIM_GROUP',
`MAILMAN_GROUP = confEXIM_GROUP',
`MAILMAN_GROUP = mail'
)
')
')

ifelse(SECTION, `ROUTERS', `dnl
mailman_router:
	driver			= accept
	require_files		= MAILMAN_HOME/lists/$local_part/config.pck
	local_part_suffix_optional
	local_part_suffix	= -bounces : -bounces+* : \
				-confirm+* : -join : -leave : \
				-owner : -request : -admin
	transport		= mailman_transport
')

ifelse(SECTION, `TRANSPORTS', `dnl
mailman_transport:
	driver			= pipe
	command			= MAILMAN_WRAP \
		''`${if def:local_part_suffix \
			{${sg{$local_part_suffix}{-(\\w+)(\\+.*)?}{\$1}}} \
			{post}}''` \
		$local_part
	current_directory	= MAILMAN_HOME
	home_directory		= MAILMAN_HOME
	user			= MAILMAN_USER
	group			= MAILMAN_GROUP
')