#!/bin/sh

include(confFEATURES_DIR/`cfhead.m4')dnl
include(confM4_DIR`/conf.default')dnl
include(confSITE_DIR/`conf')dnl

ifelse(confAWL, `SQLITE', `
if [ -f /usr/local/bin/sqlite3 ] ; then
	echo "confAWL_SQLITE_DELETE" | /usr/local/bin/sqlite3 confAWL_SQLITE_FILE
elif [ -f /usr/bin/sqlite3 ] ; then
	echo "confAWL_SQLITE_DELETE" | /usr/bin/sqlite3 confAWL_SQLITE_FILE
else
	echo "confAWL_SQLITE_DELETE" | sqlite3 confAWL_SQLITE_FILE
fi
')

ifelse(confAWL, `MYSQL', `
mysql_host=EXTRACT_DELIMITED(`1', `/', confMYSQL)
mysql_db=EXTRACT_DELIMITED(`2', `/', confMYSQL)
mysql_user=EXTRACT_DELIMITED(`3', `/', confMYSQL)
mysql_pass=EXTRACT_DELIMITED(`4', `/', confMYSQL)
if [ -f /usr/local/bin/mysql ] ; then
	MYSQL=/usr/local/bin/mysql
elif [ -f /usr/bin/mysql ] ; then
	MYSQL=/usr/bin/mysql
else
	MYSQL=mysql
fi
echo "confAWL_MYSQL_DELETE" | ${MYSQL} -h ${mysql_host} -u${mysql_user} -p"${mysql_pass}" ${mysql_db}
')

ifelse(confAWL, `DBM', `
cache_file=confAWL_DBM_FILE
confCONTRIB_DIR/awl/awl_dbm_del_expired.pl ${cache_file}
')


ifelse(confAWL, `REDIS', `PASSWORD=EXTRACT_DELIMITED(`3', `/', confREDIS)')
changequote([[, ]])
ifelse(confAWL, [[REDIS]], [[

NOW=$(date +%s)

(echo "AUTH $PASSWORD" ; echo "KEYS *" ; echo "QUIT") | redis-cli | grep ^awl: | while read KEY ; do
	VALUE=`(echo "AUTH $PASSWORD" ; echo "GET $KEY" ; echo "QUIT") | redis-cli | tail -n +2`
	if [ ! -z "$VALUE" ] && [ $VALUE -lt $NOW ] ; then
		echo "delete AWL cached record for key $KEY"
		(echo "AUTH $PASSWORD" ; echo "DEL $KEY" ; echo "QUIT") | redis-cli
	fi
done
]])
changequote