dnl
dnl добавление поля Authentication-Results с результатами проверки резолвинга
dnl рилея отправителя, результатами проверки соответствия адреса рилея
dnl отправителя SPF записи домена отправителя и результатами проверки DKIM
dnl подписи:
dnl NO		- не добавлять поле Authentication-Results
dnl YES		- добавлять Authentication-Results с самостоятельно собранным занчением
dnl DEFAULT	- добавлять поле Authentication-Results с использованием ${authresults {$smtp_active_hostname}} (exim 4.91 и выше)
dnl define(`confAUTH_RESULTS_ADD', `NO')dnl
dnl
dnl действие для существующих заголовков Authentication-Results:
dnl RENAME	- переименование старых заголовков (в конец имени добавляется -Old)
dnl REMOVE	- удаление старых заголовков
dnl NOTHING	- оставлять заголовки без изменений
dnl define(`confAUTH_RESULTS_OLD_HEADERS', `REMOVE')dnl
dnl
dnl имя хоста сервера, используемое в заголовке Authentication-Results
dnl по умолчанию используется smtp_active_hostname
dnl define(`confAUTH_RESULTS_HOSTNAME', `')dnl
dnl

ifdef(`confAUTH_RESULTS_HOSTNAME', `ifelse(len(X`'confAUTH_RESULTS_HOSTNAME), `1', `dnl
define(`confAUTH_RESULTS_HOSTNAME', `$smtp_active_hostname')dnl
')', `dnl
define(`confAUTH_RESULTS_HOSTNAME', `$smtp_active_hostname')dnl
') dnl

ifelse(confAUTH_RESULTS_OLD_HEADERS, `REMOVE', `dnl
	warn	acl		= acl_remove_header Authentication-Results
') dnl ifelse(confAUTH_RESULTS_OLD_HEADERS, `REMOVE', `')
ifelse(confAUTH_RESULTS_OLD_HEADERS, `RENAME', `dnl
	warn	acl		= acl_remove_header Authentication-Results
RENAME_HEADERS(Authentication-Results)
') dnl ifelse(confAUTH_RESULTS_OLD_HEADERS, `RENAME', `')
ifelse_strstr(confAUTH_RESULTS_ADD, `YES', `dnl
	warn	condition	= ${if def:acl_m_auth_results{no}{yes}}
		! hosts		= +relay_from_hosts
		! authenticated	= *
		set acl_m_auth_results = ; none
	warn	condition	= ${if def:acl_m_auth_results{yes}{no}}
#		add_header	= :at_start:Authentication-Results: $smtp_active_hostname${acl_m_auth_results}
		set acl_m_auth_results_header = Authentication-Results: confAUTH_RESULTS_HOSTNAME${acl_m_auth_results}
		acl		= acl_add_header "$acl_m_auth_results_header" yes
		set acl_m_auth_results_short = ${sg{Authentication-Results: confAUTH_RESULTS_HOSTNAME${acl_m_auth_results}}{\N;\r?\n\s+auth=[^\r\n]*\N}{}}
') dnl ifelse_strstr(confAUTH_RESULTS_ADD, `YES', `')
ifelse_strstr(confAUTH_RESULTS_ADD, `DEFAULT', `dnl
	warn	\
#		add_header	= :at_start:${authresults {$smtp_active_hostname}}
		set acl_m_auth_results_header = ${authresults {$smtp_active_hostname}}
		acl		= acl_add_header "$acl_m_auth_results_header" yes
		set acl_m_auth_results_default_short = ${sg{${authresults{confAUTH_RESULTS_HOSTNAME}}}{\N;\r?\n\s+auth=[^\r\n]*\N}{}}
') dnl ifelse_strstr(confAUTH_RESULTS_ADD, `DEFAULT', `')