divert(-1)
#
# Copyright (c) 2003, 2004 Victor Ustugov <victor+sendmail@corvax.kiev.ua>
# This hack is under BSD License 
# Redistributions of source code must retain the above copyright notice
#
# hacks disscussion's maillist - http://www.mta.org.ua/mailman/listinfo/sendmail-conf
#
#
# Check digits count in sender HELO/EHLO
# Проверка dial-up/dsl/cable рилеев по HELO/EHLO
#
ifdef(`_CHECK_HELO_DIALUP_DIGITS_', `dnl', `dnl
dnl
divert(0)
VERSIONID(`$Id: check_helo_dialup_digits.m4,v 8.12-0.01 2004/08/20 10:27:19 corvax Exp $')dnl
divert(-1)
dnl
define(`_CHECK_HELO_DIALUP_DIGITS_')
dnl
ifelse(len(X`'_ARG_),`1',`
errprint(`*** ERROR: HACK(check_helo_dialup_digits) requires max digits count and optional error message
')')
dnl
ifdef(`_CHECK_HELO_DIALUP_',`',`
errprint(`*** ERROR: HACK(check_helo_dialup_digits) requires HACK(check_helo)
')')
dnl
')dnl
dnl
dnl
LOCAL_CONFIG
dnl
dnl
define(`_REGEX_TMP_', `repeat_str(`', `[0-9].*', _ARG_)[0-9]')
ifelse(len(X`'_ARG2_),`1',`
HACK(`check_helo_dialup_regex', _REGEX_TMP_, `550 Access denied. Too many digits in sender helo')
', `
HACK(`check_helo_dialup_regex', _REGEX_TMP_, _ARG2_)
')