divert(-1)
#
# Copyright (c) 2003, 2004 Victor Ustugov <victor+sendmail@corvax.kiev.ua>
# This hack is under BSD License 
# Redistributions of source code must retain the above copyright notice
#
# hacks disscussion's maillist - http://www.mta.org.ua/mailman/listinfo/sendmail-conf
#
#
# Check dial-up/dsl/cable relays
# Проверка dial-up/dsl/cable рилеев
#
ifdef(`_CHECK_RELAY_DIALUP_REGEX_', `dnl', `dnl
dnl
divert(0)
VERSIONID(`$Id: check_relay_dialup_regex.m4,v 8.12-0.02 2004/08/30 11:49:16 corvax Exp $')dnl
divert(-1)
dnl
define(`_CHECK_RELAY_DIALUP_REGEX_')dnl
dnl
ifelse(len(X`'_ARG_),`1',`
errprint(`*** ERROR: HACK(check_relay_dialup_regex) requires regex and optional error message
')')
dnl
ifdef(`_CHECK_RELAY_DIALUP_',`',`
errprint(`*** ERROR: HACK(check_relay_dialup_regex) requires HACK(check_relay_dialup)
')')
dnl
ifdef(`confCHECK_RELAY_DIALUP',`',`
define(`confCHECK_RELAY_DIALUP', `CLIENT_NAME')
')
')dnl
dnl
dnl
LOCAL_CONFIG
dnl
dnl
ifdef(`confCHECK_RELAY_DIALUP_REGEX_NO', `
define(`confCHECK_RELAY_DIALUP_REGEX_TMP', `eval(confCHECK_RELAY_DIALUP_REGEX_NO + 1)')
define(`confCHECK_RELAY_DIALUP_REGEX_NO', confCHECK_RELAY_DIALUP_REGEX_TMP)
', `
define(`confCHECK_RELAY_DIALUP_REGEX_NO', `0')
')
dnl
Kdulpat_relay_`'confCHECK_RELAY_DIALUP_REGEX_NO regex -a@MATCH _ARG_
dnl
dnl
LOCAL_RULESETS
dnl
dnl
SLocal_check_dialup_relay
dnl
ifelse(len(X`'_ARG2_),`1',`
define(`_MSG_', `"550 Access from dsl/dial-up/cable relays denied according to the local policy"')
', `
define(`_MSG_', `"_ARG2_"')
')
dnl
ifelse_strstr(confCHECK_RELAY_DIALUP, `CLIENT_NAME', `dnl
R $* $| $*		$: $(dulpat_relay_`'confCHECK_RELAY_DIALUP_REGEX_NO $1 $: $1 $) $| $2
R @MATCH $| $*		$#error $@ 5.7.1 $: _MSG_
')

ifelse_strstr(confCHECK_RELAY_DIALUP, `CLIENT_PTR', `dnl
R $* $| $*		$: $1  $| $2 $| $(dulpat_relay_`'confCHECK_RELAY_DIALUP_REGEX_NO $&{client_ptr} $: $&{client_ptr} $)
R $* $| $* $| @MATCH	$#error $@ 5.7.1 $: _MSG_
R $* $| $* $| $*	$: $1 $| $2
')